VSI OpenVMS Forum

Code: Select all

> I have the logical set up on both nodes:
> "QMAN$MASTER" = "$1$DKA100:[CLUSTER$CONFIG.Q]"

   Ok, but are the files therein accessible from all the nodes?  Is that
disk mounted on all the cluster members?  Is that logical name so
defined on all nodes?

   Does the problem affect batch jobs, too, or only print jobs?

   Do SHOW QUEUE commands work on all nodes?  For example:

      SHOW QUEUE /ALL /BATCH
      SHOW QUEUE /ALL /DEVI = PRINT

Code: Select all

> [...] it is not the problem of the QUEUE_MANAGER, but the
> Print-Symbiont failing to access the file to be printed. [...]

   Certainly the "PSM" in "%PSM-E-OPENIN" is suggestive.  No doubt, the
smart move would have been:

      help /message /facility = PSM OPENIN

(Or it might have been if that worked.)


> [...] the node where the queue manager is running DID NOT have access
> to the disk/file being printed from the other node.

   Around here, there are (30-year-old) DCL scripts on every node to
help with that kind of thing.  SYS$MANAGER:MOUNT_DISKS_LOCAL.COM mounts
the local disks.  It gets run very early in
SYS$MANAGER:SYSTARTUP_VMS.COM.  Then, after DECnet has been started,
SYS$MANAGER:MOUNT_DISKS_REMOTE.COM gets the MOUNT_DISKS_LOCAL.COM
scripts from all the other cluster nodes, and runs them on the
up-starting system.  It may not be good, but it's old:

ITS $ type SYS$MANAGER:MOUNT_DISKS_REMOTE.COM
$!                                              30 January 1991.  SMS.
$!
$! Mount all disks on other cluster members, using the other cluster members'
$! "MOUNT_DISKS_LOCAL.COM" command procedures.  This procedure depends on proxy
$! logins for SYSTEM on all other nodes in the cluster.
$!
$! The lexical function F$CSID() is new in VMS V5.4.
$!
$ SET NOON
$!
$ THIS_NODE = F$EDIT( F$GETSYI( "NODENAME"), "TRIM")
$ CONTEXT = ""
$!
$! Get a cluster member node name.
$!
$ NODE_LOOP:
$!
$    NODE_ID = F$CSID( CONTEXT)
$!
$! Quit after the last node in the cluster.
$!
$    IF  NODE_ID .EQS. ""  THEN  GOTO  END_NODE_LOOP
$!
$! Get the cluster node's node name.
$!
$    NODE = F$GETSYI( "NODENAME", , NODE_ID)
$!
$! If the cluster node is not this node, run its MOUNT_DISKS_LOCAL.COM.
$!
$    IF  NODE .NES. THIS_NODE
$    THEN
$!
$! Form the remote MOUNT_DISKS_LOCAL.COM file name.
$!
$       MOUNT_FILE_NAME = "''NODE'::MOUNT_DISKS_LOCAL.COM"
$!
$! Loop for a while, if the file is not accessible.  The network may not be
$! ready immediately.
$!
$       COUNT = 30
$!
$ SEARCH_LOOP:
$!
$       IF  F$SEARCH( MOUNT_FILE_NAME) .EQS. ""
$       THEN
$          COUNT = COUNT- 1
$          IF  COUNT .GT. 0
$          THEN
$             WAIT  00:00:01
$             GOTO SEARCH_LOOP
$          ENDIF
$       ENDIF
$!
$       @  'MOUNT_FILE_NAME'  'NODE'
$!
$! Print a message, if the file (access) fails.
$!
$       IF  .NOT. $STATUS
$       THEN
$          STATUS = $STATUS
$          WRITE  SYS$OUTPUT  ""
$          WRITE  SYS$OUTPUT  "   Error mounting disks for node ''NODE'."
$          WRITE  SYS$OUTPUT  "      "+ F$MESSAGE( STATUS)+ "."
$          WRITE  SYS$OUTPUT  ""
$       ENDIF
$!
$    ENDIF
$!
$ GOTO  NODE_LOOP
$ END_NODE_LOOP:
$!
$ EXIT
$!